This puzzle consists of protected sheets 1-9, each describing how to extract a letter. This is further complicated by most sheets being hidden, preventing solvers from even looking at the sheet directly (since unhiding is prevented by the protection). Here is how you can solve each one:

1. The center column: In the working sheet, enter the formula

   =columns('1. The center column'!1:1)

   . This returns 15, indicating that there are 15 columns in the first row of the sheet. The center column is therefore the 8th, or H.
2. The number of rows: In the working sheet, enter the formula

   =rows('2. The number of rows'!A:A)

   . This returns 9, corresponding to the letter I.
3. The one nonempty cell: This sheet is not hidden! You can either use the technique of the next sheet, or you can Ctrl-F for A, B, C, etc. until you get a hit. The value itself is colored white, so solvers are unlikely to find it visually. One way or another, the one nonempty cell contains N.
4. The one nonempty cell: Like the previous, but now the sheet is hidden. In the working sheet, enter the formula

   =join("", flatten('4. The one nonempty cell'!A:Z))

   . (There's no reason why the spreadsheet must only contain the default columns A-Z, so you might first choose to check how many columns there are in a strategy like in the first sheet.) This joins together all values in all cells, yielding D.
5. The total number of cells: In the working sheet, enter the following formula:

   =rows('5. The total number of cells'!A:A)
   *columns('5. The total number of cells'!1:1)

   This yields 18, corresponding to the letter R.
6. The shape formed by the nonempty cells: This one is trickier; a simple thing to do is to just fill a formula like

   ='6. The shape formed by the nonempty cells'!A1

   from A1 of the working sheet to every cell, then look visually. A fancier formula is something like

   =let(therows, byrow('6. The shape formed by the nonempty cells'!A:Z,
   lambda(therow, join("", bycol(therow,
   lambda(thecell, if(thecell="", " ", thecell)))))),
   join(char(10), filter(therows, len(trim(therows))>0)))

   The result of the fancier formula (when displayed in a fixed width font) is:

           #                 
          # #                
          # #                
         #   #               
         #   #               
         #####               
         #   #               
         #   #               
         #   #               

   which is clearly the letter A.
7. sum(even vals) - sum(odd vals): A formula like

   =let(allvals, flatten('7. sum(even vals) - sum(odd vals)'!A:Z),
   sum(filter(allvals, mod(allvals,2)=0))-sum(filter(allvals, mod(allvals,2)=1)))

   yields 14, giving an N.
8. The bottommost nonempty cell:

   flatten()

   turns an array into a single column, in usual left-to-right, top-to-bottom reading order, and thus its last nonempty entry will be the desired result.

   =right(join("", flatten('8. The bottommost nonempty cell'!A:Z)))

   is a simple way to get the answer, which is C.
9. The letter E: This one simply rewards the solver for having the idea to look if there are any hidden sheets. As it says on the tin, take the letter E.

Putting together these letters gives the answer HINDRANCE.